/* Copyright John Gilbertson 2005                      */
/* This code is for educational purposes only.         */
/* You may not copy any part of this code for any use. */
/* Built with processing, http://www.processing.org/   */

class ring
{
  int s,r,w,n;
  float speed;
  float angle;
  color c;
  boolean[] missing;
  ring(int _s, int _r, int _w, int _n, float _speed, color _c)
  {
    s=_s;
    r=_r;
    w=_w;
    n=_n;
    c=_c;
    speed=_speed;
    if(random(100)>50.0)
      speed=speed*-1;
    speed=speed/2.0 + random(speed/2.0);
    missing=new boolean[s];
    if(n>=s)
    {
      n=s-1;
    }
    if(n<5 && c!=color(0,0,255))
    {
      n=5;
    }
    while(n>0)
    {
      int x=(int)random(s);
      if(!missing[x])
      {
        missing[x]=true;
        n--;
      }
    }
  }
  
  void draw()
  {
    angle+=speed;
    push();
    translate(width/2,height/2);
    rotateZ(angle);
    float dt=TWO_PI/(float)s;
    fill(c);
    for(int i=0;i<s;i++)
    {
      if(!missing[i])
      {
        beginShape(QUADS);
        {
          vertex(r*sin(dt*i),r*cos(dt*i));
          vertex(r*sin(dt*(i+1)),r*cos(dt*(i+1)));
          vertex((r+w)*sin(dt*(i+1)),(r+w)*cos(dt*(i+1)));
          vertex((r+w)*sin(dt*i),(r+w)*cos(dt*i));
        }
        endShape();
      }
    }
    pop();
  }
}

class player
{
  int x,y;
  player(int _x, int _y)
  {
    x=_x;
    y=_y;
  }
  
  void move()
  {
    if(keys[0])
      x+=2+(level/4);
    if(keys[1])
      y+=2+(level/4);
    if(keys[2])
      x-=2+(level/4);
    if(keys[3])
      y-=2+(level/4);
  }
  
  boolean check_and_draw()
  {
    if(red(get(x,y))!=0)
    {
      fill(0,0,255);
      ellipse(x-2,y-2,5,5);
      return true;
    }
    else
    {
      move();
      fill(0,255,0);
      ellipse(x-2,y-2,5,5);
      return false;
    }     
  }
  
  boolean win()
  {
    if(blue(get(x,y))!=0)
    {
      return true;
    }
    return false;
  }
}

void mousePressed()
{
  click=true;
}

void mouseReleased()
{
  click=false;
}

void keyPressed()
{
  if(key==RIGHT)
    keys[0]=true;
  if(key==DOWN)
    keys[1]=true;
  if(key==LEFT)
    keys[2]=true;
  if(key==UP)
    keys[3]=true;
}

void keyReleased()
{
  if(key==RIGHT)
    keys[0]=false;
  if(key==DOWN)
    keys[1]=false;
  if(key==LEFT)
    keys[2]=false;
  if(key==UP)
    keys[3]=false; 
}

void ring_setup()
{
  a[0]=new ring(16,30,25,(32-level)/2,0.04+(level/600.0),color(255,0,0));
  a[1]=new ring(16,55,25,(32-level)/2,0.04+(level/600.0),color(255,0,0));
  a[2]=new ring(32,85,25,(32-level),0.04+(level/600.0),color(255,0,0));
  a[3]=new ring(32,115,25,(32-level),0.04+(level/600.0),color(255,0,0));
  a[4]=new ring(32,145,25,(32-level),0.04+(level/600.0),color(255,0,0));
  a[5]=new ring(32,175,50,0,0,color(0,0,255));
  
}

ring[] a;
int level;
player fred;
boolean[] keys;
boolean click;
BFont f;
int time;
int start=0;

void setup()
{
  size(400,400);
  f=loadFont("Futura-Light.vlw.gz");
  textFont(f,20);
  framerate(15);
  noStroke();
  keys=new boolean[4];
  for(int i=0;i<keys.length;i++)
    keys[i]=false;
  fred=new player(width/2, height/2);
  a=new ring[6];
  level=0;
  time=0;
  ring_setup();
}

void loop()
{
  background(0);
//  translate(width/2,height/2);

  for(int i=0;i<a.length;i++)
  {
    a[i].draw();
  }

  if(start==0)
  {
    fill(255,255,255);
    textFont(f,32);
    text("Click to start",width/2-60,height/2+80);
    if(click)
    {
      start=1;
      setup();
    }
  }
    
  if(fred.win() && level <25 && start==1)
  {
    level++;
    fred=new player(width/2,height/2);
    ring_setup(); 
  }
  else if(fred.win() && level==25)
  {
    start=0;
    fill(255,255,255);
    textFont(f,32);
    text("You win!",width/2-60,height/2);
    text("Your Time: "+ time,width/2-60,height/2+20);
  }
  else if(start==1)
  {
    if(!fred.check_and_draw())
      time++;
    else
      time+=5;
  }
  fill(255,255,255);
  textFont(f,20);
  text("Level: "+level,10,height-10);
  text("Time: "+time,width-100,height-10);
}