star[] stars;
ship foo;
float xp=0;
rock[] rocks;
BFont f;
int score;
int numrocks=30;
int numstars=600;
int newgame=1;
int paused=0;

void setup()
{
  size(200,400);
  f=loadFont("Futura-Light.vlw.gz");
  textFont(f,16);

  background(0);
  stars=new star[numstars];
  for(int i=0;i<numstars;i++)
  {
    stars[i]=new star((int)random(width+200)-100,(int)random(height*3)-(height*2),random(1.7)+0.1);
  }
  rocks=new rock[numrocks];
  for(int i=0;i<numrocks;i++)
  {
    rocks[i]=new rock(random(width+30)-15,-1000-random(height*2),random(4)+4,random(TWO_PI));
  }

  foo=new ship(width/2,100);
  foo.shields=-10;  
}

void keyPressed()
{
  if(key == 'p' || key == 'P')
  {
    paused=(paused+1)%2;
  }
}

void loop()
{
  if(paused==1)
  {
    return;
  }
  if(foo.shields>=0)
  {
    background(0);

    fill(color(0,255,0));
    textFont(f,20);
    stroke(255,255,255);
    text("Shields:" + foo.shields,2,20);
    fill(color(255,255,0));
    text("Score:" +score,width-80,20);

    push();
    translate(0,height/2);
    rotateX(PI/5.0);

    xp+=0.01;
    score++;
    for(int i=0;i<numstars;i++)
    {
      stars[i].draw();
    }

    for(int i=0;i<numrocks;i++)
    {
      rocks[i].draw();
      if((rocks[i].y+5)>(foo.y-10) && (rocks[i].y-5<foo.y+10) && rocks[i].x+5>foo.x-10 && rocks[i].x-5<foo.x+10)
      {
        foo.boom();
      }
    }
    foo.draw();
    if(keyPressed)
    {
      if(key==LEFT)
      foo.moveLeft();
      else if(key==RIGHT)
      foo.moveRight();
    }
    else
    foo.moveForward();
    pop();
  }
  else
  {
    if(newgame!=1)
    {
      fill(255,255,0);
      textFont(f,35);
      text("GAME OVER",(width/2)-66,height/2);
      textFont(f,22);
      text("Hit SPACE to restart",(width/2)-66,height/2+30);
    }
    else
    {
      textFont(f,22);
      text("Click to start",40,200);
    }
    if(keyPressed || (mousePressed && newgame==1))
    {
      if(key==' ' || (mousePressed && newgame==1))
      {
        newgame=0;
        foo.shields=1000;
        score=0;
        for(int i=0;i<numrocks;i++)
        {
          rocks[i]=new rock(random(width+30)-15,-1000-random(2*height),random(4)+4,random(TWO_PI));
        }
      }
    }
  }
}

class rock
{
  float x,y,speed,r;

  rock(float _x, float _y, float _speed, float _r)
  {
    x=_x;
    y=_y;
    speed=_speed;
    r=_r;
  }

  void move()
  {
    y=y+speed;
    if(y>200)
    {
      speed=random(2)+4;
      x=random(width+30)-15;
      y=0-2*height;
    }
  }

  void draw()
  {
    move();
    push();
    translate(x,y);
    rotateZ(r);
    stroke(0,255,0);
    line(6,0,4,-8);
    line(4,-8,-2,-10);
    line(-2,-10,-8,-4);
    line(-8,-4,-6,4);
    line(-6,4,4,6);
    line(4,6,1,1);
    line(1,1,6,0);
    pop();
  }
}

class ship
{
  float x,y;
  float r;
  int shields=1000;
  trail smoke;

  ship(int _x, int _y)
  {
    x=_x;
    y=_y;
    smoke=new trail(x,y);
  }

  void draw()
  {
    smoke.spawn(x,y);
    smoke.draw();
    stroke(0,255,0);
    x=x+3*sin(r);

    push();
    translate(x,y);
    rotate(r);
    line(10,10,0,-10);
    line(-10,10,0,-10);
    line(10,10,0,5);
    line(-10,10,0,5);
    pop();
  }

  void moveRight()
  {
    if(x>(width-25))
    moveForward();
    else
    {
      r=r+PI/20.0;
      if(r>PI/4.0)
      {
        r=PI/4.0;
      }
    }
  }

  void moveForward()
  {
    if(r>0)
    {
      r-=(PI/40.0);
      if(r<0)
      r=0;
    }
    else if(r<0)
    {
      r+=(PI/40.0);
      if(r>0)
      r=0;
    }
    else
    r=0;
  }

  void moveLeft()
  {
    if(x<25)
    moveForward();
    else
    {
      r=r-(PI/40.0);
      if(r<(0-(PI/4.0)))
      {
        r=0-(PI/4.0);
      }
    }
  }

  void boom()
  {
    shields-=10;
    push();
    translate(x,y);
    noFill();
    stroke(255,255,0);
    ellipse(-15,-15,30,30);
    pop();
  }

}

class trail
{

  particle[] bits;
  int x;
  trail(float _x, float _y)
  {
    x=0;
    bits=new particle[400];
    for(int i=0;i<400;i++)
    {
      bits[i]=new particle(_x,_y);
    }
  }

  void draw()
  {
    for(int i=0;i<bits.length;i++)
    {
      bits[i].draw();
    }
  }

  void spawn(float _x,float _y)
  {
    for(int i=0;i<5;i++)
    {
      bits[(x+i)%400]=new particle(_x,_y+3);
    }
    x=(x+5)%400;
  }
}

class particle
{
  float x,y;
  int life;

  particle(float _x, float _y)
  {
    x=_x+(random(4)-2);
    y=_y+(random(4)-2);
    life=60;
  }
  void move()
  {
    y=y+2;
    life--;
  }
  void draw()
  {
    life=life-1;
    move();
    push();
    translate(x,y);
    stroke((life*5),life*10-255,0);
    line(0,0,0,1);
    pop();
  }
}

class star
{
  int x;
  float y;
  float speed;
  star(int _x, int _y, float _speed)
  {
    x=_x;
    y=(float)_y;
    speed=_speed;
  }

  void move()
  {
    y=y+3*speed;
    if(y>200)
    {
      y=0-height*2;
      speed=random(1.7)+0.1;
    }
  }

  void draw()
  {
    //    set(x,(int)y,0);
    move();
    stroke(color(150*speed+40,150*speed+40,150*speed+40));
    line(x,(int)y,x,y+speed);
  }

}